cmatanisomatfic.for

Go to the documentation of this file.

      SUBROUTINE cmatanisomatfic(CMANISOMATFIC,M0,DANISO,UNIT2,DET,NDI)
C
C>    ANISOTROPIC MATRIX: MATERIAL 'FICTICIOUS' ELASTICITY TENSOR
      IMPLICIT NONE
      include 'PARAM_UMAT.INC'
C
      INTEGER NDI,I,J,K,L
      DOUBLE PRECISION CMANISOMATFIC(ndi,ndi,ndi,ndi),UNIT2(ndi,ndi),
     1                 m0(ndi,ndi),daniso(3),det
      DOUBLE PRECISION CINV4(ndi,ndi,ndi,ndi),CINV14(ndi,ndi,ndi,ndi)
      DOUBLE PRECISION D2UDI4,D2UDI1DI4
      DOUBLE PRECISION IMM(ndi,ndi,ndi,ndi),MMI(ndi,ndi,ndi,ndi),
     1                 mm0(ndi,ndi,ndi,ndi)
C
C-----------------------------------------------------------------------------
      !2ND DERIVATIVE OF SSEANISO IN ORDER TO I4
      d2udi4=daniso(2)
      !2ND DERIVATIVE OF SSEANISO IN ORDER TO I1 AND I4
      d2udi1di4=daniso(3)
C
      CALL tensorprod2(m0,m0,mm0,ndi)
      CALL tensorprod2(unit2,m0,imm,ndi)
      CALL tensorprod2(m0,unit2,mmi,ndi)
C
      DO i=1,ndi
       DO j=1,ndi
         DO k=1,ndi
          DO l=1,ndi
          cinv4(i,j,k,l)=d2udi4*mm0(i,j,k,l)
          cinv14(i,j,k,l)=d2udi1di4*(imm(i,j,k,l)+mmi(i,j,k,l))
          cmanisomatfic(i,j,k,l)=four*(cinv4(i,j,k,l)+cinv14(i,j,k,l))
          END DO
         END DO
       END DO
      END DO
C
      RETURN
      END SUBROUTINE cmatanisomatfic