metiso.for

Go to the documentation of this file.

      SUBROUTINE metiso(CMISO,CMFIC,PL,PKISO,PKFIC,C,UNIT2,DET,NDI)
C>    ISOCHORIC MATERIAL ELASTICITY TENSOR
      IMPLICIT NONE
      include 'PARAM_UMAT.INC'
C
      INTEGER NDI,I1,J1,K1,L1
      DOUBLE PRECISION UNIT2(ndi,ndi),PL(ndi,ndi,ndi,ndi),
     1                 cmiso(ndi,ndi,ndi,ndi),pkiso(ndi,ndi),
     2                 cmfic(ndi,ndi,ndi,ndi),pkfic(ndi,ndi),
     3                 cisoaux(ndi,ndi,ndi,ndi),
     4                 cisoaux1(ndi,ndi,ndi,ndi),c(ndi,ndi),
     5                 plt(ndi,ndi,ndi,ndi),cinv(ndi,ndi),
     6                 pll(ndi,ndi,ndi,ndi)
      DOUBLE PRECISION TRFIC,XX,YY,ZZ,DET,AUX,AUX1
C
      CALL matinv3d(c,cinv,ndi)
      cisoaux1=zero
      cisoaux=zero
      CALL contraction44(cisoaux1,pl,cmfic,ndi)
C      
C  transpose of lagrangian projection tensor     
      DO i1=1,ndi
        DO j1=1,ndi
           DO k1=1,ndi
              DO l1=1,ndi
                plt(i1,j1,k1,l1)=pl(k1,l1,i1,j1)
              END DO
            END DO
         END DO
      END DO
C
      CALL contraction44(cisoaux,cisoaux1,plt,ndi)
C
      trfic=zero
      aux=det**(-two/three)
      aux1=aux**two
      DO i1=1,ndi
         trfic=trfic+aux*pkfic(i1,i1)*c(i1,i1)
      END DO
C
      DO i1=1,ndi
        DO j1=1,ndi
           DO k1=1,ndi
              DO l1=1,ndi
                xx=aux1*cisoaux(i1,j1,k1,l1)
                pll(i1,j1,k1,l1)=(one/two)*(cinv(i1,k1)*cinv(j1,l1)+
     1                                      cinv(i1,l1)*cinv(j1,k1))-
     2                           (one/three)*cinv(i1,j1)*cinv(k1,l1)
                yy=trfic*pll(i1,j1,k1,l1)
                zz=pkiso(i1,j1)*cinv(k1,l1)+cinv(i1,j1)*pkiso(k1,l1)
C
                cmiso(i1,j1,k1,l1)=xx+(two/three)*yy-(two/three)*zz
              END DO
           END DO
        END DO
      END DO
C
      RETURN
      END SUBROUTINE metiso