setiso.for

Go to the documentation of this file.

      SUBROUTINE setiso(CISO,CFIC,PE,SISO,SFIC,UNIT2,NDI)
C>    ISOCHORIC SPATIAL ELASTICITY TENSOR
      IMPLICIT NONE
      include 'PARAM_UMAT.INC'
C
      INTEGER NDI,I1,J1,K1,L1
      DOUBLE PRECISION UNIT2(ndi,ndi),PE(ndi,ndi,ndi,ndi),
     1                 ciso(ndi,ndi,ndi,ndi),siso(ndi,ndi),
     2                 cfic(ndi,ndi,ndi,ndi),sfic(ndi,ndi),
     3                 cisoaux(ndi,ndi,ndi,ndi),
     4                 cisoaux1(ndi,ndi,ndi,ndi)
      DOUBLE PRECISION TRFIC,XX,YY,ZZ
C
      cisoaux1=zero
      cisoaux=zero

      CALL contraction44(cisoaux1,pe,cfic,ndi)      
      CALL contraction44(cisoaux,cisoaux1,pe,ndi)
C
      trfic=zero
      DO i1=1,ndi
         trfic=trfic+sfic(i1,i1)
      END DO
C
      DO i1=1,ndi
        DO j1=1,ndi
           DO k1=1,ndi
              DO l1=1,ndi
                xx=cisoaux(i1,j1,k1,l1)
                yy=trfic*pe(i1,j1,k1,l1)
                zz=siso(i1,j1)*unit2(k1,l1)+unit2(i1,j1)*siso(k1,l1)
C                
                ciso(i1,j1,k1,l1)=xx+(two/three)*yy-(two/three)*zz
              END DO
           END DO
        END DO
      END DO
C
      RETURN
      END SUBROUTINE setiso